ꦫꦣꦺꦤ꧀ꦄꦤ꧀ꦠꦱꦺꦤ

PATH: usr / sbin

#! /usr/local/cpanel/3rdparty/perl/542/bin/perl

# Copyright (c) The Exim Maintainers 2020 - 2025
# Copyright (c) 2007-2017 University of Cambridge.
# See the file NOTICE for conditions of use and distribution.
# SPDX-License-Identifier: GPL-2.0-or-later

use warnings;
use strict;
BEGIN { pop @INC if $INC[-1] eq '.' };

use Pod::Usage;
use Getopt::Long qw(:config no_ignore_case);
use File::Basename;

# Except when they appear in comments, the following placeholders in this
# source are replaced when it is turned into a runnable script:
#
# PERL_COMMAND
# ZCAT_COMMAND
# COMPRESS_SUFFIX
# MSGID_RE

# This file has been so processed.

# This is a perl script which extracts from an Exim log all entries
# for all messages that have an entry that matches a given pattern.
# If *any* entry for a particular message matches the pattern, *all*
# entries for that message are displayed.

# We buffer up information on a per-message basis. It is done this way rather
# than reading the input twice so that the input can be a pipe.

# There must be one argument, which is the pattern. Subsequent arguments
# are the files to scan; if none, the standard input is read. If any file
# appears to be compressed, it is passed through zcat. We can't just do this
# for all files, because zcat chokes on non-compressed files.

# Performance optimized in 02/02/2007 by Jori Hamalainen
# Typical run time acceleration: 4 times

use POSIX qw(mktime);

# Insert MSGID_RE
# Start msgid.frag
# Copyright (c) The Exim Maintainers 2025
# SPDX-License-Identifier: GPL-2.0-or-later
#
# Regex patterns for exim message-id

# Simple matching

my $b62 = "[[:alnum:]]";

my $msgid_sec_re = "${b62}{6}";
my $msgid_pid_new_re = "${b62}{11}";
my $msgid_pid_old_re = "${b62}{6}";
my $msgid_frc_new_re = "${b62}{4}";
my $msgid_frc_old_re = "${b62}{2}";

my $msgid_new_re = "$msgid_sec_re-$msgid_pid_new_re-$msgid_frc_new_re";
my $msgid_old_re = "$msgid_sec_re-$msgid_pid_old_re-$msgid_frc_old_re";
my $msgid_re =     "(?:$msgid_new_re|$msgid_old_re)";

# Match with content submatches
# - requires variables seconds, pid, fractions

my $msgid_sec_cap_re = "(?<seconds>$msgid_sec_re)";
my $msgid_pid_cap_re = "(?<pid>(?:$msgid_pid_new_re|$msgid_pid_old_re))";
my $msgid_frc_cap_re = "(?<fractions>(?:$msgid_frc_new_re|$msgid_frc_old_re))";

my $msgid_cap_re = "(?:$msgid_sec_cap_re-$msgid_pid_cap_re-$msgid_frc_cap_re)";

# End msgid.frag

# This subroutine converts a time/date string from an Exim log line into
# the number of seconds since the epoch. It handles optional timezone
# information.

sub seconds
  {
  my($year,$month,$day,$hour,$min,$sec,$tzs,$tzh,$tzm) =
    $_[0] =~ /^(\d{4})-(\d\d)-(\d\d)\s(\d\d):(\d\d):(\d\d)(?:.\d+)?(?>\s([+-])(\d\d)(\d\d))?/o;

my $seconds = mktime $sec, $min, $hour, $day, $month - 1, $year - 1900;

if (defined $tzs)
    {
    $seconds -= $tzh * 3600 + $tzm * 60 if $tzs eq "+";
    $seconds += $tzh * 3600 + $tzm * 60 if $tzs eq "-";
    }

return $seconds;
  }

# This subroutine processes a single line (in $_) from a log file. Program
# defensively against short lines finding their way into the log.

my (%saved, %id_list, $pattern);

my $queue_time  = -1;
my $insensitive = 1;
my $invert      = 0;
my $related     = 0;
my $use_pager   = 1;
my $literal     = 0;

# If using "related" option, have to track extra message IDs
my $related_re='';
my @Mids = ();

sub do_line
  {

# Convert syslog lines to mainlog format, as in eximstats.

if (!/^\d{4}-/o) { $_ =~ s/^.*? exim\b.*?: //o; }

return unless
    my($date,$id) = /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d(?:\.\d+)? (?:[+-]\d{4} )?)(?:\[\d+\] )?($msgid_re)?/o;

# Handle the case when the log line belongs to a specific message. We save
  # lines for specific messages until the message is complete. Then either print
  # or discard.

if (defined $id)
    {
    $saved{$id} = '' unless defined($saved{$id});

# Save up the data for this message in case it becomes interesting later.

$saved{$id} .= $_;

# Are we interested in this id ? Short circuit if we already were interested.

if ($invert)
      {
      $id_list{$id} = 1 if (!defined($id_list{$id}));
      $id_list{$id} = 0 if (($insensitive && /$pattern/io) || /$pattern/o);
      }
    else
      {
      if (defined $id_list{$id} ||
	($insensitive && /$pattern/io) || /$pattern/o)
	{
	$id_list{$id} = 1;
	get_related_ids($id) if $related;
	}
      elsif ($related && $related_re)
	{
	grep_for_related($_, $id);
	}
      }

# See if this is a completion for some message. If it is interesting,
    # print it, but in any event, throw away what was saved.

if (index($_, 'Completed') != -1 ||
	index($_, 'SMTP data timeout') != -1 ||
	  (index($_, 'rejected') != -1 &&
	    /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d(?:\.\d+)? (?:[+-]\d{4} )?)(?:\[\d+\] )?$msgid_re rejected/o))
      {
      if ($queue_time != -1 &&
	  $saved{$id} =~ /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d ([+-]\d{4} )?)/o)
	{
	my $old_sec = &seconds($1);
	my $sec = &seconds($date);
	$id_list{$id} = 0 if $id_list{$id} && $sec - $old_sec <= $queue_time;
	}

print "$saved{$id}\n" if ($id_list{$id});
      delete $id_list{$id};
      delete $saved{$id};
      }
    }

# Handle the case where the log line does not belong to a specific message.
  # Print it if it is interesting.

elsif ( ($invert && (($insensitive && !/$pattern/io) || !/$pattern/o)) ||
	 (!$invert && (($insensitive &&  /$pattern/io) ||  /$pattern/o)) )
    { print "$_\n"; }
  }

# Rotated log files are frequently compressed and there are a variety of
# formats it could be compressed with. Rather than use just one that is
# detected and hardcoded at Exim compile time, detect and use what the
# logfile is compressed with on the fly.
#
# List of known compression extensions and their associated commands:
my $compressors = {
  gz   => { cmd => 'zcat',  args => '' },
  bz2  => { cmd => 'bzcat', args => '' },
  xz   => { cmd => 'xzcat', args => '' },
  lzma => { cmd => 'lzma',  args => '-dc' },
  zst  => { cmd => 'zstdcat', args => '' },
};
my $csearch = 0;

sub detect_compressor_bin
  {
  my $ext = shift();
  my $c = $compressors->{$ext}->{cmd};
  $compressors->{$ext}->{bin} = `which $c 2>/dev/null`;
  chomp($compressors->{$ext}->{bin});
  }

sub detect_compressor_capable
  {
  my $filename = shift();
  map { &detect_compressor_bin($_) } keys %$compressors
    if (!$csearch);
  $csearch = 1;
  return undef
    unless (grep {$filename =~ /\.(?:$_)$/} keys %$compressors);
  # Loop through them, figure out which one it detected,
  # and build the commandline.
  my $cmdline = undef;
  foreach my $ext (keys %$compressors)
    {
    if ($filename =~ /\.(?:$ext)$/)
      {
      # Just die if compressor not found; if this occurs in the middle of
      # two valid files with a lot of matches, error could easily be missed.
      die("Didn't find $ext decompressor for $filename\n")
        if ($compressors->{$ext}->{bin} eq '');
      $cmdline = $compressors->{$ext}->{bin} ." ".
                   $compressors->{$ext}->{args};
      last;
      }
    }
  return $cmdline;
  }

sub grep_for_related
  {
  my ($line,$id) = @_;
  $id_list{$id} = 1 if $line =~ m/$related_re/;
  }

sub get_related_ids
  {
  my ($id) = @_;
  push @Mids, $id unless grep /\b$id\b/, @Mids;
  my $re = join '|', @Mids;
  $related_re = qr/$re/;
  }

# The main program. Extract the pattern and make sure any relevant characters
# are quoted if the -l flag is given. The -t flag gives a time-on-queue value
# which is an additional condition. The -M flag will also display "related"
# loglines (msgid from matched lines is searched in following lines).

GetOptions(
    'I|sensitive' => sub { $insensitive = 0 },
      'l|literal' => \$literal,
      'M|related' => \$related,
      't|queue-time=i' => \$queue_time,
      'pager!'         => \$use_pager,
      'v|invert'       => \$invert,
      'h|help'         => sub { pod2usage(-exit => 0, -verbose => 1) },
      'm|man'          => sub {
        pod2usage(
            -exit      => 0,
            -verbose   => 2,
            -noperldoc => system('perldoc -V 2>/dev/null >&2')
        );
      },
      'version'        => sub {
            print basename($0) . ": $0\n",
                "build: 4.99.1\n",
                "perl(runtime): $]\n";
            exit 0;
      },
) and @ARGV or pod2usage;

$pattern = shift @ARGV;
$pattern = quotemeta $pattern if $literal;

# Start a pager if output goes to a terminal
if (-t 1 and $use_pager)
  {
  # for perl >= v5.10.x: foreach ($ENV{PAGER}//(), 'less', 'more')
  foreach (defined $ENV{PAGER} ? $ENV{PAGER} : (), 'less', 'more')
    {
    local $ENV{LESS} .= ' --no-init --quit-if-one-screen';
    open(my $pager, '|-', $_) or next;
    select $pager;
    last;
    }
  }

# If file arguments are given, open each one and process according as it is
# is compressed or not.

if (@ARGV)
  {
  foreach (@ARGV)
    {
    my $filename = $_;
    if (-x '/bin/zcat' && $filename =~ /\.(?:gz)$/o)
      {
      open(LOG, "/bin/zcat $filename |") ||
        die "Unable to zcat $filename: $!\n";
      }
    elsif (my $cmdline = &detect_compressor_capable($filename))
      {
      open(LOG, "$cmdline $filename |") ||
        die "Unable to decompress $filename: $!\n";
      }
    else
      {
      open(LOG, "<$filename") || die "Unable to open $filename: $!\n";
      }
    do_line() while (<LOG>);
    close(LOG);
    }
  }

# If no files are named, process STDIN only

else { do_line() while (<STDIN>); }

# At the end of processing all the input, print any uncompleted messages.

for (keys %id_list)
  {
  print "+++ $_ has not completed +++\n$saved{$_}\n";
  }

__END__

=head1 NAME

exigrep - search Exim's main log

=head1 SYNOPSIS

B<exigrep> [options] pattern [log] ...

=head1 DESCRIPTION

The B<exigrep> utility is a Perl script that searches one or more main log
files for entries that match a given pattern.  When it finds  a  match,
it  extracts  all  the  log  entries for the relevant message, not just
those that match the pattern.  Thus, B<exigrep> can extract  complete  log
entries  for  a  given  message, or all mail for a given user, or for a
given host, for example.

If no file names are given on the command line, the standard input is read.

For known file extensions indicating compression (F<.gz>, F<.bz2>, F<.xz>,
F<.lzma>, and F<.zst>) a suitable de-compressor is used, if available.

The output is sent through a pager if a terminal is connected to STDOUT. As
pager are considered: C<$ENV{PAGER}>, C<less>, C<more>.

=head1 OPTIONS

=over

=item B<-l>|B<--literal>

This means 'literal', that is, treat all characters in the
pattern  as standing for themselves.  Otherwise the pattern must be a
Perl regular expression.  The pattern match is case-insensitive.

=item B<-t>|B<--queue-time> I<seconds>

Limit the output to messages that spent at least I<seconds> in the
queue.

=item B<-I>|B<--sensitive>

Do a case sensitive search.

=item B<-v>|B<--invert>

Invert the meaning of the search pattern. That is, print message log
entries that are not related to that pattern.

=item B<-M>|B<--related>

Search for related messages too.

=item B<--no-pager>

Do not use a pager, even if STDOUT is connected to a terminal.

=item B<-h>|B<--help>

Print a short reference help. For more detailed help try L<exigrep(8)>,
or C<exigrep --man>.

=item B<-m>|B<--man>

Print this manual page of B<exigrep>.

=back

=head1 SEE ALSO

L<exim(8)>, L<perlre(1)>, L<Exim|http://exim.org/>

=head1 AUTHOR

This  manual  page  was stitched together from spec.txt by Andreas Metzler L<ametzler at downhill.at.eu.org>
and updated by Heiko Schlittermann L<hs@schlittermann.de>.

=cut

# vim:ft=perl:

[+] ..
[-] exim_fixdb [edit]
[-] getpolicyload [edit]
[-] bpftool [edit]
[-] xfs_growfs [edit]
[-] kpatch [edit]
[-] pivot_root [edit]
[-] fsfreeze [edit]
[-] named-checkzone [edit]
[-] xfs_info [edit]
[-] lvm [edit]
[-] paperconfig [edit]
[-] pure-config.pl [edit]
[-] vgextend [edit]
[-] xfs_logprint [edit]
[-] xfsdump [edit]
[-] faillock [edit]
[-] eximstats [edit]
[-] grpck [edit]
[-] iptables-translate [edit]
[-] pwconv [edit]
[-] xfs_ncheck [edit]
[-] iptables-restore [edit]
[-] xfs_admin [edit]
[-] xfs_fsr [edit]
[-] key.dns_resolver [edit]
[-] ping [edit]
[-] iptables-nft [edit]
[-] whmapi1 [edit]
[-] nfsdclnts [edit]
[-] lnewusers [edit]
[-] chkconfig [edit]
[-] ip6tables-restore [edit]
[-] validatetrans [edit]
[-] vgconvert [edit]
[-] luserdel [edit]
[-] mkfs.minix [edit]
[-] thin_migrate [edit]
[-] pvck [edit]
[-] mkfs.ext4 [edit]
[-] rpcinfo [edit]
[-] lvmdump [edit]
[-] cache_restore [edit]
[-] readprofile [edit]
[-] arptables-nft-restore [edit]
[-] mountstats [edit]
[-] sysctl [edit]
[-] ctstat [edit]
[-] tcpdump [edit]
[-] ping6 [edit]
[-] blkdiscard [edit]
[-] atd [edit]
[-] avcstat [edit]
[-] xtables-nft-multi [edit]
[-] pwunconv [edit]
[-] ownership [edit]
[-] ethtool [edit]
[-] mtr-packet [edit]
[-] xfs_repair [edit]
[-] setquota [edit]
[-] adcli [edit]
[-] update-pciids [edit]
[-] rpc.statd [edit]
[-] grpunconv [edit]
[-] cache_metadata_size [edit]
[-] chcpu [edit]
[-] exim_dumpdb [edit]
[-] runq [edit]
[-] nfsdcld [edit]
[-] intel_sdsi [edit]
[-] getpcaps [edit]
[-] atrun [edit]
[-] request-key [edit]
[-] thin_ls [edit]
[-] iptables-restore-translate [edit]
[-] rdisc [edit]
[-] iprupdate [edit]
[-] addpart [edit]
[-] sm-notify [edit]
[-] e2image [edit]
[-] grub2-bios-setup [edit]
[-] vgremove [edit]
[-] era_check [edit]
[-] dhclient-script [edit]
[-] e2undo [edit]
[-] mkdict [edit]
[-] mpathconf [edit]
[-] pdata_tools [edit]
[-] anacron [edit]
[-] pure-ftpwho [edit]
[-] unix_chkpwd [edit]
[-] cracklib-packer [edit]
[-] tracepath6 [edit]
[-] rtcwake [edit]
[-] clock [edit]
[-] chroot [edit]
[-] ifstat [edit]
[-] iscsistart [edit]
[-] ebtables-save [edit]
[-] pure-ftpd [edit]
[-] dnssec-keyfromlabel [edit]
[-] route [edit]
[-] lvmconfig [edit]
[-] setpci [edit]
[-] iprdump [edit]
[-] lvmsar [edit]
[-] crond [edit]
[-] vgimportdevices [edit]
[-] iscsid [edit]
[-] vgimport [edit]
[-] iprconfig [edit]
[-] thin_restore [edit]
[-] dnssec-dsfromkey [edit]
[-] lvremove [edit]
[-] rndc-confgen [edit]
[-] nfsdclddb [edit]
[-] depmod [edit]
[-] arptables-save [edit]
[-] logrotate [edit]
[-] fsck.xfs [edit]
[-] vgcfgbackup [edit]
[-] semanage [edit]
[-] pvs [edit]
[-] unsquashfs [edit]
[-] vgchange [edit]
[-] genl [edit]
[-] ebtables-translate [edit]
[-] selabel_get_digests_all_partial_matches [edit]
[-] hwclock [edit]
[-] pure-authd [edit]
[-] delpart [edit]
[-] vgmerge [edit]
[-] lvmsadc [edit]
[-] grub2-switch-to-blscfg [edit]
[-] exim_dbmbuild [edit]
[-] mount.nfs4 [edit]
[-] zramctl [edit]
[-] e2freefrag [edit]
[-] ldattach [edit]
[-] xfs_io [edit]
[-] mariadbd [edit]
[-] rpcdebug [edit]
[-] sfdisk [edit]
[-] reboot [edit]
[-] init [edit]
[-] convertquota [edit]
[-] partx [edit]
[-] suexec [edit]
[-] smartd [edit]
[-] lsmod [edit]
[-] xfs_mdrestore [edit]
[-] nameif [edit]
[-] era_restore [edit]
[-] pure-mrtginfo [edit]
[-] selinux_check_access [edit]
[-] grub2-install [edit]
[-] groupdel [edit]
[-] thin_dump [edit]
[-] vigr [edit]
[-] dmeventd [edit]
[-] mkfs.msdos [edit]
[-] install-info [edit]
[-] imunify-notifier [edit]
[-] alternatives [edit]
[-] selinuxconlist [edit]
[-] visudo [edit]
[-] pure-uploadscript [edit]
[-] tmpwatch [edit]
[-] lfd [edit]
[-] ip6tables-nft-save [edit]
[-] dnssec-verify [edit]
[-] dump-acct [edit]
[-] exiqsumm [edit]
[-] ipset [edit]
[-] sefcontext_compile [edit]
[-] dovecot [edit]
[-] lgroupmod [edit]
[-] sasldblistusers2 [edit]
[-] grpconv [edit]
[-] selabel_lookup_best_match [edit]
[-] udevadm [edit]
[-] newusers [edit]
[-] sestatus [edit]
[-] dump-utmp [edit]
[-] grub2-get-kernel-settings [edit]
[-] lspci [edit]
[-] service [edit]
[-] ss [edit]
[-] blkdeactivate [edit]
[-] mklost+found [edit]
[-] era_invalidate [edit]
[-] rdma [edit]
[-] ebtables-restore [edit]
[-] ip6tables-translate [edit]
[-] dnssec-revoke [edit]
[-] fsck.vfat [edit]
[-] tune2fs [edit]
[-] iscsiuio [edit]
[-] selinuxdefcon [edit]
[-] mke2fs [edit]
[-] auditd [edit]
[-] mkswap [edit]
[-] genhostid [edit]
[-] dnssec-keygen [edit]
[-] nologin [edit]
[-] nfsdcltrack [edit]
[-] dmidecode [edit]
[-] named-checkconf [edit]
[-] sos [edit]
[-] setcap [edit]
[-] fcgistarter [edit]
[-] sa [edit]
[-] grub2-reboot [edit]
[-] ldconfig [edit]
[-] grub2-probe [edit]
[-] pvchange [edit]
[-] groupmems [edit]
[-] vdpa [edit]
[-] NetworkManager [edit]
[-] exim_tidydb [edit]
[-] genhomedircon [edit]
[-] xfs_quota [edit]
[-] groupadd [edit]
[-] semodule [edit]
[-] dnssec-keymgr [edit]
[-] lvdisplay [edit]
[-] rpcctl [edit]
[-] mysqld [edit]
[-] fsck.minix [edit]
[-] thin_repair [edit]
[-] ctrlaltdel [edit]
[-] accton [edit]
[-] umount.nfs [edit]
[-] start-statd [edit]
[-] dosfsck [edit]
[-] pdns_server [edit]
[-] quotastats [edit]
[-] grub2-set-default [edit]
[-] lusermod [edit]
[-] arp [edit]
[-] ebtables-nft [edit]
[-] selabel_digest [edit]
[-] httpd_ls_bak_bak [edit]
[-] shutdown [edit]
[-] fsck.ext4 [edit]
[-] augenrules [edit]
[-] lgroupadd [edit]
[-] lvm_import_vdo [edit]
[-] lvcreate [edit]
[-] pvresize [edit]
[-] logsave [edit]
[-] dnssec-coverage [edit]
[-] arptables-nft [edit]
[-] setsebool [edit]
[-] parted [edit]
[-] ebtables-nft-save [edit]
[-] ip6tables [edit]
[-] mkfs [edit]
[-] ip [edit]
[-] cache_check [edit]
[-] vgsplit [edit]
[-] exiqgrep [edit]
[-] kexec [edit]
[-] tracepath [edit]
[-] iconvconfig [edit]
[-] grub2-macbless [edit]
[-] dcb [edit]
[-] dovecot_cpshutdown [edit]
[-] lgroupdel [edit]
[-] adduser [edit]
[-] raid-check [edit]
[-] multipathd [edit]
[-] modsec-sdbm-util [edit]
[-] xtables-monitor [edit]
[-] halt [edit]
[-] pwhistory_helper [edit]
[-] blkid [edit]
[-] ifenslave [edit]
[-] mount.fuse [edit]
[-] accessdb [edit]
[-] update-smart-drivedb [edit]
[-] sosreport [edit]
[-] gssproxy [edit]
[-] grub2-set-password [edit]
[-] groupmod [edit]
[-] restorecon [edit]
[-] fdformat [edit]
[-] filefrag [edit]
[-] plymouthd [edit]
[-] fstrim [edit]
[-] dnssec-checkds [edit]
[-] selabel_partial_match [edit]
[-] cryptsetup [edit]
[-] e4crypt [edit]
[-] ledmon [edit]
[-] showmount [edit]
[-] chronyd [edit]
[-] makedumpfile [edit]
[-] xfsrestore [edit]
[-] tuned-adm [edit]
[-] fsck.ext2 [edit]
[-] dosfslabel [edit]
[-] swapoff [edit]
[-] firewalld [edit]
[-] pvscan [edit]
[-] lvmdevices [edit]
[-] applygnupgdefaults [edit]
[-] md-auto-readd.sh [edit]
[-] xfs_freeze [edit]
[-] resizepart [edit]
[-] rpc.idmapd [edit]
[-] plymouth-set-default-theme [edit]
[-] ip6tables-nft-restore [edit]
[-] partprobe [edit]
[-] matchpathcon [edit]
[-] nscd [edit]
[-] vgdisplay [edit]
[-] vgck [edit]
[-] rtkitctl [edit]
[-] selabel_lookup [edit]
[-] cache_dump [edit]
[-] mkfs.cramfs [edit]
[-] ebtables-nft-restore [edit]
[-] unix_update [edit]
[-] fsck.msdos [edit]
[-] telinit [edit]
[-] lvchange [edit]
[-] swaplabel [edit]
[-] selinuxexeccon [edit]
[-] pidof [edit]
[-] lvmdiskscan [edit]
[-] mkdumprd [edit]
[-] autrace [edit]
[-] iprdbg [edit]
[-] fdisk [edit]
[-] thin_metadata_unpack [edit]
[-] lvs [edit]
[-] whmapi0 [edit]
[-] iprsos [edit]
[-] blockdev [edit]
[-] xfs_db [edit]
[-] ipset-translate [edit]
[-] tsig-keygen [edit]
[-] edquota [edit]
[-] xfs_mkfile [edit]
[-] resize2fs [edit]
[-] rtacct [edit]
[-] exicyclog [edit]
[-] vipw [edit]
[-] vgexport [edit]
[-] lvscan [edit]
[-] xfs_rtcp [edit]
[-] vgscan [edit]
[-] selinuxenabled [edit]
[-] dnssec-importkey [edit]
[-] grubby [edit]
[-] pvdisplay [edit]
[-] g13-syshelp [edit]
[-] exim [edit]
[-] exim_checkaccess [edit]
[-] rtmon [edit]
[-] arping [edit]
[-] csf [edit]
[-] restorecon_xattr [edit]
[-] lid [edit]
[-] vgrename [edit]
[-] fsadm [edit]
[-] nfsidmap [edit]
[-] getsebool [edit]
[-] kpartx [edit]
[-] cracklib-format [edit]
[-] vgmknodes [edit]
[-] realm [edit]
[-] sssd [edit]
[-] fuser [edit]
[-] zic [edit]
[-] fsck [edit]
[-] grub2-set-bootflag [edit]
[-] iptunnel [edit]
[-] thin_check [edit]
[-] plipconfig [edit]
[-] runuser [edit]
[-] ebtables [edit]
[-] iprinit [edit]
[-] vgimportclone [edit]
[-] nvme [edit]
[-] rpc.mountd [edit]
[-] pvcreate [edit]
[-] devlink [edit]
[-] named-journalprint [edit]
[-] badblocks [edit]
[-] blkmapd [edit]
[-] losetup [edit]
[-] named-compilezone [edit]
[-] mkfs.xfs [edit]
[-] quotaoff [edit]
[-] rmmod [edit]
[-] xqmstats [edit]
[-] hdparm [edit]
[-] e4defrag [edit]
[-] arptables [edit]
[-] ipmaddr [edit]
[-] mpathpersist [edit]
[-] e2fsck [edit]
[-] xfs_bmap [edit]
[-] quotaon [edit]
[-] cracklib-unpacker [edit]
[-] lpasswd [edit]
[-] vmcore-dmesg [edit]
[-] mksquashfs [edit]
[-] era_dump [edit]
[-] pam_console_apply [edit]
[-] xfsinvutil [edit]
[-] pwck [edit]
[-] dnssec-signzone [edit]
[-] e2mmpstatus [edit]
[-] arptables-restore [edit]
[-] quotacheck [edit]
[-] ip6tables-restore-translate [edit]
[-] dhclient [edit]
[-] poweroff [edit]
[-] packer [edit]
[-] named-nzd2nzf [edit]
[-] mdmon [edit]
[-] xfs_estimate [edit]
[-] blkzone [edit]
[-] consoletype [edit]
[-] mdadm [edit]
[-] capsh [edit]
[-] whmlogin [edit]
[-] fsck.fat [edit]
[-] usermod [edit]
[-] iptables-nft-restore [edit]
[-] rcmysql [edit]
[-] nfsstat [edit]
[-] iscsi-iname [edit]
[-] mii-diag [edit]
[-] sendmail [edit]
[-] rpc.nfsd [edit]
[-] modinfo [edit]
[-] sulogin [edit]
[-] thin_metadata_pack [edit]
[-] userdel [edit]
[-] rsyslogd [edit]
[-] nfsconf [edit]
[-] biosdecode [edit]
[-] sw-engine-fpm [edit]
[-] pam_namespace_helper [edit]
[-] rotatelogs [edit]
[-] findfs [edit]
[-] tc [edit]
[-] rtstat [edit]
[-] lvreduce [edit]
[-] ifconfig [edit]
[-] tuned [edit]
[-] fix-info-dir [edit]
[-] luseradd [edit]
[-] lchage [edit]
[-] sshd [edit]
[-] exinext [edit]
[-] ddns-confgen [edit]
[-] exportfs [edit]
[-] ip6tables-save [edit]
[-] swapon [edit]
[-] tcpslice [edit]
[-] lvmpolld [edit]
[-] getenforce [edit]
[-] vgs [edit]
[-] apachectl [edit]
[-] addgnupghome [edit]
[-] vgreduce [edit]
[-] cfdisk [edit]
[-] smartctl [edit]
[-] nft [edit]
[-] useradd [edit]
[-] dmsetup [edit]
[-] nstat [edit]
[-] lnstat [edit]
[-] mkhomedir_helper [edit]
[-] sos-collector [edit]
[-] irqbalance-ui [edit]
[-] grub2-setpassword [edit]
[-] getpidprevcon [edit]
[-] cache_writeback [edit]
[-] iscsiadm [edit]
[-] insmod [edit]
[-] mount.nfs [edit]
[-] nfsiostat [edit]
[-] pam_timestamp_check [edit]
[-] switch_root [edit]
[-] rpc.gssd [edit]
[-] e2label [edit]
[-] pure-quotacheck [edit]
[-] load_policy [edit]
[-] mpathcleanup [edit]
[-] multipath [edit]
[-] thin_trim [edit]
[-] update-alternatives [edit]
[-] vgcreate [edit]
[-] exigrep [edit]
[-] getcap [edit]
[-] named [edit]
[-] ether-wake [edit]
[-] runlevel [edit]
[-] iptables [edit]
[-] aureport [edit]
[-] pvmove [edit]
[-] mkfs.fat [edit]
[-] lvresize [edit]
[-] arptables-nft-save [edit]
[-] mcelog [edit]
[-] cracklib-check [edit]
[-] tipc [edit]
[-] xfs_spaceman [edit]
[-] xfs_metadump [edit]
[-] start-stop-daemon [edit]
[-] ip6tables-nft [edit]
[-] iptables-save [edit]
[-] fsck.ext3 [edit]
[-] umount.nfs4 [edit]
[-] dumpe2fs [edit]
[-] chgpasswd [edit]
[-] lshw [edit]
[-] cache_repair [edit]
[-] vgcfgrestore [edit]
[-] exim_lock [edit]
[-] mii-tool [edit]
[-] weak-modules [edit]
[-] xfs_copy [edit]
[-] vpddecode [edit]
[-] rndc [edit]
[-] thin_rmap [edit]
[-] ledctl [edit]
[-] create-cracklib-dict [edit]
[-] lvconvert [edit]
[-] nsec3hash [edit]
[-] wipefs [edit]
[-] repquota [edit]
[-] bridge [edit]
[-] virt-what-cvm [edit]
[-] mkfs.ext2 [edit]
[-] mtr [edit]
[-] mkfs.vfat [edit]
[-] chpasswd [edit]
[-] rpcbind [edit]
[-] dnssec-settime [edit]
[-] ausearch [edit]
[-] mkfs.ext3 [edit]
[-] exiwhat [edit]
[-] virt-what [edit]
[-] modprobe [edit]
[-] dmstats [edit]
[-] thin_metadata_size [edit]
[-] dmfilemapd [edit]
[-] sss_cache [edit]
[-] agetty [edit]
[-] auditctl [edit]
[-] fixfiles [edit]
[-] thin_delta [edit]
[-] slattach [edit]
[-] nfsref [edit]
[-] fatlabel [edit]
[-] saslpasswd2 [edit]
[-] debugfs [edit]
[-] rfkill [edit]
[-] iptables-nft-save [edit]
[-] dnssec-cds [edit]
[-] grub2-mkconfig [edit]
[-] installkernel [edit]
[-] setenforce [edit]
[-] pure-certd [edit]
[-] mkdosfs [edit]
[-] httpd [edit]
[-] pvremove [edit]
[-] fsck.cramfs [edit]
[-] lvrename [edit]
[-] irqbalance [edit]
[-] lvextend [edit]
[-] htcacheclean [edit]
[-] setfiles [edit]